ESP32-CAMというカメラ付きESP32マイコンモジュールで、カメラで撮影した画像をSDカードに保存してみた

ESP32-CAMというカメラ付きESP32マイコンモジュールで、カメラで撮影した画像をSDカードに保存してみた。

ESP32-CAMは技適マーク無しなので、電波を出さないでSDカードに画像を保存するというソフトを作るのを試した。
以下は、最初に撮影した第1枚目の画像で、90度向きが回転しているが、ノートPCの脇に置いていたESP32-CAMでノートPCの液晶画面を横のほうから撮影されたものだ。 しかも、カメラのレンズの保護シールを張ったままなのでなんか曇った感じになっている。

Arduino IDEの環境でESP32関係のexampleがいろいろとあるのだが、そのうちのCameraWebServerというコードを元にしてWebServer部分を全部削除してカメラだけまず動かした。
そして、カメラから取得したJPEGデータを、SDカード(microSD)に保存するという部分を付け足して作成した。
SDカード関係は、Arduino IDEのexampleのSD_MMCというライブラリのexampleを元にして書いてみた。

ソースコードは以下のとおり。

#include "esp_camera.h"
#include "FS.h"
#include "SD_MMC.h"

// Select camera model
//#define CAMERA_MODEL_WROVER_KIT
//#define CAMERA_MODEL_ESP_EYE
//#define CAMERA_MODEL_M5STACK_PSRAM
//#define CAMERA_MODEL_M5STACK_WIDE
#define CAMERA_MODEL_AI_THINKER

#include "camera_pins.h"

void setup() {
  Serial.begin(115200);
  Serial.setDebugOutput(true);
  Serial.println();

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;
  //init with high specs to pre-allocate larger buffers
  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA;
    config.jpeg_quality = 10;
    config.fb_count = 2;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;
    config.fb_count = 1;
  }

#if defined(CAMERA_MODEL_ESP_EYE)
  pinMode(13, INPUT_PULLUP);
  pinMode(14, INPUT_PULLUP);
#endif

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    return;
  }

  sensor_t * s = esp_camera_sensor_get();
  //initial sensors are flipped vertically and colors are a bit saturated
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1);//flip it back
    s->set_brightness(s, 1);//up the blightness just a bit
    s->set_saturation(s, -2);//lower the saturation
  }
  //drop down frame size for higher initial frame rate
  s->set_framesize(s, FRAMESIZE_QVGA);

#if defined(CAMERA_MODEL_M5STACK_WIDE)
  s->set_vflip(s, 1);
  s->set_hmirror(s, 1);
#endif


  if(!SD_MMC.begin()){
    Serial.println("Card Mount Failed");
    return;
  }

  camera_fb_t * fb = NULL;

  fb = esp_camera_fb_get();
  if (!fb) {
    Serial.println("Camera capture failed");
    return;
  }
  if (fb->len <= 0) {
    Serial.println("capture data size error");
    return;
  }
  
  File file = SD_MMC.open("/test.jpg", FILE_WRITE);
  if(!file){
    Serial.println("Failed to open file for writing");
    return;
  }

  if (file.write(fb->buf, fb->len)) {
    Serial.println("File written");
  } else {
    Serial.println("Write failed");
  }
  file.close();
  
  esp_camera_fb_return(fb);

  Serial.println("Finished.");
  
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(10000);
}

このソースの他にCameraWebServerのスケッチに含まれるcamera_pins.hとcamera_index.hというヘッダファイルが必要だ。

動作としては、電源を入れると、勝手に起動してカメラを初期化し、画像を1枚JPEGモードで撮影し、それをSDカード(microSD)にtest.jpgというファイル名で保存するというものだ。

UARTにデバッグ情報が表示されるので、動かない場合は、それを見るとどこで不具合がでているかがわかるだろう。

何度か動かしたうち、うまく動かない場合もあって、なぜかカメラがサポートしていない品物だと誤判定されたり、microSDカードが使えないという判定が出たりすることがあった。しかし、その直後にリセットボタンでリセットを掛けると普通に動いたりしていたので、原因はよくわからなかった。

実用に使う場合にはエラーのチェックをもっとしっかりやって、リトライ処理とかを付け加えたほうがいいだろう。

ESP32-CAMというカメラ付きESP32マイコンモジュールで、カメラで撮影した画像をSDカードに保存してみた」への6件のフィードバック

  1. にーちゃ

    ソースコードをそのまま参考にさせて頂いて、M5camera F で実装しようとしたのですが、コンパイルの段階で「’amp’ was not declared in this scope」(57行目)のエラーが出てしまったのですが、そもそも’amp’とは何でしょうか。ご教授いただければ幸いです。

    返信
    1. kako 投稿作成者

      blogに使っているwordpressのプラグインの機能でソースコードを掲示したのですが、どうも一部が文字化けしてしまったようです。
      ampというのは、HTML特殊文字コードでアンパサンド「&」のコードを表現するのに使うもののようです。
      57行目のこの部分は
      esp_err_t err = esp_camera_init(&config);
      となっております。

      返信
  2. きい

    このページとても参考になりました。
    ESP32CAMで監視カメラを作ろうとしております。
    動画をSDカードに保存することは可能でしょうか?
    やはり静止画しか無理でしょうか?

    返信
    1. kako 投稿作成者

      このカメラモジュールの機能としてJPEGなどの静止画像だけしかサポートされてないみたいなので、動画は無理だと思われます。代わりにソフトで動画化(エンコード)するのはメモリや処理能力が足らないのでこれも不可能だろうと思います。

      返信
  3. きい

    お返事いただきありがとうございます。
    残念ですが動画の保存は無理なのですね。
    教えていただきありがとうございました。

    返信

saunashio へ返信する コメントをキャンセル

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

Time limit is exhausted. Please reload CAPTCHA.

− 3 = 2